571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
51 lines
1.1 KiB
Nix
51 lines
1.1 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, cmake
|
|
, unstableGitUpdater
|
|
, testers
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "rapidcheck";
|
|
version = "0-unstable-2023-12-14";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "emil-e";
|
|
repo = "rapidcheck";
|
|
rev = "ff6af6fc683159deb51c543b065eba14dfcf329b";
|
|
hash = "sha256-Ixz5RpY0n8Un/Pv4XoTfbs40+70iyMbkQUjDqoLaWOg=";
|
|
};
|
|
|
|
outputs = [ "out" "dev" ];
|
|
|
|
nativeBuildInputs = [ cmake ];
|
|
|
|
cmakeFlags = [
|
|
(lib.cmakeBool "BUILD_SHARED_LIBS" (!stdenv.hostPlatform.isStatic))
|
|
(lib.cmakeBool "RC_INSTALL_ALL_EXTRAS" true)
|
|
];
|
|
|
|
passthru = {
|
|
updateScript = unstableGitUpdater { };
|
|
tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "C++ framework for property based testing inspired by QuickCheck";
|
|
inherit (finalAttrs.src.meta) homepage;
|
|
maintainers = [ ];
|
|
license = licenses.bsd2;
|
|
pkgConfigModules = [
|
|
"rapidcheck"
|
|
# Extras
|
|
"rapidcheck_boost"
|
|
"rapidcheck_boost_test"
|
|
"rapidcheck_catch"
|
|
"rapidcheck_doctest"
|
|
"rapidcheck_gtest"
|
|
];
|
|
platforms = platforms.all;
|
|
};
|
|
})
|