e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
80 lines
2.3 KiB
Nix
80 lines
2.3 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchurl
|
|
, fetchFromGitHub
|
|
, makeWrapper
|
|
, meson
|
|
, ninja
|
|
, pkg-config
|
|
, runtimeShell
|
|
, installShellFiles
|
|
|
|
, android-tools
|
|
, ffmpeg
|
|
, libusb1
|
|
, SDL2
|
|
}:
|
|
|
|
let
|
|
version = "2.7";
|
|
prebuilt_server = fetchurl {
|
|
name = "scrcpy-server";
|
|
inherit version;
|
|
url = "https://github.com/Genymobile/scrcpy/releases/download/v${version}/scrcpy-server-v${version}";
|
|
hash = "sha256-ojxWWfNsJg8QXAItJ7yz6v/6JgcOe6qe2mbQE3ehrbo=";
|
|
};
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
pname = "scrcpy";
|
|
inherit version;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "Genymobile";
|
|
repo = "scrcpy";
|
|
rev = "refs/tags/v${version}";
|
|
hash = "sha256-OBMm/GkiIdZaJd9X62vY4M6FVKiHTBwqRtH220bYej4=";
|
|
};
|
|
|
|
# display.c: When run without a hardware accelerator, this allows the command to continue working rather than failing unexpectedly.
|
|
# This can happen when running on non-NixOS because then scrcpy seems to have a hard time using the host OpenGL-supporting hardware.
|
|
# It would be better to fix the OpenGL problem, but that seems much more intrusive.
|
|
postPatch = ''
|
|
substituteInPlace app/src/display.c \
|
|
--replace "SDL_RENDERER_ACCELERATED" "SDL_RENDERER_ACCELERATED || SDL_RENDERER_SOFTWARE"
|
|
'';
|
|
|
|
nativeBuildInputs = [ makeWrapper meson ninja pkg-config installShellFiles ];
|
|
|
|
buildInputs = [ ffmpeg SDL2 libusb1 ];
|
|
|
|
# Manually install the server jar to prevent Meson from "fixing" it
|
|
preConfigure = ''
|
|
echo -n > server/meson.build
|
|
'';
|
|
|
|
postInstall = ''
|
|
mkdir -p "$out/share/scrcpy"
|
|
ln -s "${prebuilt_server}" "$out/share/scrcpy/scrcpy-server"
|
|
|
|
# runtime dep on `adb` to push the server
|
|
wrapProgram "$out/bin/scrcpy" --prefix PATH : "${android-tools}/bin"
|
|
'' + lib.optionalString stdenv.hostPlatform.isLinux ''
|
|
substituteInPlace $out/share/applications/scrcpy-console.desktop \
|
|
--replace "/bin/bash" "${runtimeShell}"
|
|
'';
|
|
|
|
meta = {
|
|
description = "Display and control Android devices over USB or TCP/IP";
|
|
homepage = "https://github.com/Genymobile/scrcpy";
|
|
changelog = "https://github.com/Genymobile/scrcpy/releases/tag/v${version}";
|
|
sourceProvenance = with lib.sourceTypes; [
|
|
fromSource
|
|
binaryBytecode # server
|
|
];
|
|
license = lib.licenses.asl20;
|
|
platforms = lib.platforms.unix;
|
|
maintainers = with lib.maintainers; [ deltaevo ryand56 ];
|
|
mainProgram = "scrcpy";
|
|
};
|
|
}
|