e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
84 lines
2.2 KiB
Nix
84 lines
2.2 KiB
Nix
{ lib
|
|
, stdenv
|
|
, rustPlatform
|
|
, fetchzip
|
|
, openssl
|
|
, pkg-config
|
|
, installShellFiles
|
|
, darwin
|
|
, bash
|
|
|
|
# rbw-fzf
|
|
, withFzf ? false
|
|
, fzf
|
|
, perl
|
|
|
|
# rbw-rofi
|
|
, withRofi ? false
|
|
, rofi
|
|
, xclip
|
|
|
|
# pass-import
|
|
, withPass ? false
|
|
, pass
|
|
}:
|
|
|
|
rustPlatform.buildRustPackage rec {
|
|
pname = "rbw";
|
|
version = "1.12.1";
|
|
|
|
src = fetchzip {
|
|
url = "https://git.tozt.net/rbw/snapshot/rbw-${version}.tar.gz";
|
|
hash = "sha256-+1kalFyhk2UL+iVzuFLDsSSTudrd4QpXw+3O4J+KsLc=";
|
|
};
|
|
|
|
cargoHash = "sha256-cKbbsDb449WANGT+x8APhzs+hf5SR3RBsCBWDNceRMA=";
|
|
|
|
nativeBuildInputs = [
|
|
installShellFiles
|
|
] ++ lib.optionals stdenv.hostPlatform.isLinux [ pkg-config ];
|
|
|
|
buildInputs = [ bash ] # for git-credential-rbw
|
|
++ lib.optionals stdenv.hostPlatform.isDarwin [
|
|
darwin.apple_sdk_11_0.frameworks.Security
|
|
darwin.apple_sdk_11_0.frameworks.AppKit
|
|
];
|
|
|
|
preConfigure = lib.optionalString stdenv.hostPlatform.isLinux ''
|
|
export OPENSSL_INCLUDE_DIR="${openssl.dev}/include"
|
|
export OPENSSL_LIB_DIR="${lib.getLib openssl}/lib"
|
|
'';
|
|
|
|
postInstall = ''
|
|
install -Dm755 -t $out/bin bin/git-credential-rbw
|
|
'' + lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
|
|
installShellCompletion --cmd rbw \
|
|
--bash <($out/bin/rbw gen-completions bash) \
|
|
--fish <($out/bin/rbw gen-completions fish) \
|
|
--zsh <($out/bin/rbw gen-completions zsh)
|
|
'' + lib.optionalString withFzf ''
|
|
install -Dm755 -t $out/bin bin/rbw-fzf
|
|
substituteInPlace $out/bin/rbw-fzf \
|
|
--replace fzf ${fzf}/bin/fzf \
|
|
--replace perl ${perl}/bin/perl
|
|
'' + lib.optionalString withRofi ''
|
|
install -Dm755 -t $out/bin bin/rbw-rofi
|
|
substituteInPlace $out/bin/rbw-rofi \
|
|
--replace rofi ${rofi}/bin/rofi \
|
|
--replace xclip ${xclip}/bin/xclip
|
|
'' + lib.optionalString withPass ''
|
|
install -Dm755 -t $out/bin bin/pass-import
|
|
substituteInPlace $out/bin/pass-import \
|
|
--replace pass ${pass}/bin/pass
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Unofficial command line client for Bitwarden";
|
|
homepage = "https://crates.io/crates/rbw";
|
|
changelog = "https://git.tozt.net/rbw/plain/CHANGELOG.md?id=${version}";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ albakham luc65r ];
|
|
mainProgram = "rbw";
|
|
};
|
|
}
|