e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
54 lines
1.5 KiB
Nix
54 lines
1.5 KiB
Nix
{ lib, stdenv, fetchurl, sqlite, postgresql, zlib, acl, ncurses, openssl, readline
|
|
, CoreFoundation, IOKit
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "bacula";
|
|
version = "15.0.2";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://sourceforge/bacula/${pname}-${version}.tar.gz";
|
|
sha256 = "sha256-VVFcKmavmoa5VdrqQIk3i4ZNBRsubjA4O+825pOs6no=";
|
|
};
|
|
|
|
# libtool.m4 only matches macOS 10.*
|
|
postPatch = lib.optionalString (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64) ''
|
|
substituteInPlace configure \
|
|
--replace "10.*)" "*)"
|
|
'';
|
|
|
|
buildInputs = [ postgresql sqlite zlib ncurses openssl readline ]
|
|
++ lib.optionals stdenv.hostPlatform.isDarwin [
|
|
CoreFoundation
|
|
IOKit
|
|
]
|
|
# acl relies on attr, which I can't get to build on darwin
|
|
++ lib.optional (!stdenv.hostPlatform.isDarwin) acl;
|
|
|
|
configureFlags = [
|
|
"--with-sqlite3=${sqlite.dev}"
|
|
"--with-postgresql=${lib.getDev postgresql}"
|
|
"--with-logdir=/var/log/bacula"
|
|
"--with-working-dir=/var/lib/bacula"
|
|
"--mandir=\${out}/share/man"
|
|
] ++ lib.optional (stdenv.buildPlatform != stdenv.hostPlatform) "ac_cv_func_setpgrp_void=yes";
|
|
|
|
installFlags = [
|
|
"logdir=\${out}/logdir"
|
|
"working_dir=\${out}/workdir"
|
|
];
|
|
|
|
postInstall = ''
|
|
mkdir -p $out/bin
|
|
ln -s $out/sbin/* $out/bin
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Enterprise ready, Network Backup Tool";
|
|
homepage = "http://bacula.org/";
|
|
license = with licenses; [ agpl3Only bsd2 ];
|
|
maintainers = with maintainers; [ lovek323 eleanor ];
|
|
platforms = platforms.all;
|
|
};
|
|
}
|