e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
95 lines
2.5 KiB
Nix
95 lines
2.5 KiB
Nix
{ lib
|
|
, stdenv
|
|
, buildNpmPackage
|
|
, fetchFromGitHub
|
|
, buildPackages
|
|
, libsecret
|
|
, xcbuild
|
|
, Security
|
|
, AppKit
|
|
, pkg-config
|
|
, node-gyp
|
|
, runCommand
|
|
, vscode-js-debug
|
|
, nix-update-script
|
|
}:
|
|
|
|
buildNpmPackage rec {
|
|
pname = "vscode-js-debug";
|
|
version = "1.93.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "microsoft";
|
|
repo = "vscode-js-debug";
|
|
rev = "v${version}";
|
|
hash = "sha256-8+ZoTddzgwLwPUduT+G5zVgt/ZxLWKojz1PKvOxLX6o=";
|
|
};
|
|
|
|
npmDepsHash = "sha256-4GTZevbQg1LhxVw6WQYGvWHVuaWTwpCf50gMZWAHE7c=";
|
|
|
|
nativeBuildInputs = [
|
|
pkg-config
|
|
node-gyp
|
|
] ++ lib.optionals stdenv.hostPlatform.isDarwin [ xcbuild ];
|
|
|
|
buildInputs =
|
|
lib.optionals (!stdenv.hostPlatform.isDarwin) [ libsecret ]
|
|
++ lib.optionals stdenv.hostPlatform.isDarwin [
|
|
Security
|
|
AppKit
|
|
];
|
|
|
|
postPatch = ''
|
|
${lib.getExe buildPackages.jq} '
|
|
.scripts.postinstall |= empty | # tries to install playwright, not necessary for build
|
|
.scripts.build |= "gulp dapDebugServer" | # there is no build script defined
|
|
.bin |= "./dist/src/dapDebugServer.js" # there is no bin output defined
|
|
' ${src}/package.json > package.json
|
|
'';
|
|
|
|
makeCacheWritable = true;
|
|
|
|
npmInstallFlags = [ "--include=dev" ];
|
|
|
|
preBuild = ''
|
|
export PATH="node_modules/.bin:$PATH"
|
|
'';
|
|
|
|
passthru.updateScript = nix-update-script {
|
|
extraArgs = [ "--version-regex" "v((?!\d{4}\.\d\.\d{3}).*)" ];
|
|
};
|
|
|
|
passthru.tests.test = runCommand "${pname}-test"
|
|
{
|
|
nativeBuildInputs = [ vscode-js-debug ];
|
|
meta.timeout = 60;
|
|
} ''
|
|
output=$(js-debug --help 2>&1)
|
|
if grep -Fw -- "Usage: dapDebugServer.js [port|socket path=8123] [host=localhost]" - <<< "$output"; then
|
|
touch $out
|
|
else
|
|
echo "Expected help output was not found!" >&2
|
|
echo "The output was:" >&2
|
|
echo "$output" >&2
|
|
exit 1
|
|
fi
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "A DAP-compatible JavaScript debugger";
|
|
longDescription = ''
|
|
This is a [DAP](https://microsoft.github.io/debug-adapter-protocol/)-based
|
|
JavaScript debugger. It debugs Node.js, Chrome, Edge, WebView2, VS Code
|
|
extensions, and more. It has been the default JavaScript debugger in
|
|
Visual Studio Code since 1.46, and is gradually rolling out in Visual
|
|
Studio proper.
|
|
'';
|
|
homepage = "https://github.com/microsoft/vscode-js-debug";
|
|
changelog =
|
|
"https://github.com/microsoft/vscode-js-debug/blob/v${version}/CHANGELOG.md";
|
|
mainProgram = "js-debug";
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ zeorin ];
|
|
};
|
|
}
|