571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
43 lines
1.1 KiB
Nix
43 lines
1.1 KiB
Nix
{ lib, stdenv, fetchFromGitHub, cmake, hiredis
|
|
, enableShared ? !stdenv.hostPlatform.isStatic
|
|
, enableStatic ? stdenv.hostPlatform.isStatic
|
|
}:
|
|
|
|
# You must build at one type of library
|
|
assert enableShared || enableStatic;
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "redis-plus-plus";
|
|
version = "1.3.13";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "sewenew";
|
|
repo = "redis-plus-plus";
|
|
rev = version;
|
|
sha256 = "sha256-bZxs1qnVAkh0BO0CyP1zL/+K3NZYmFy9ryg1QcRLcmg=";
|
|
};
|
|
|
|
patches = [
|
|
./0001-Fix-pkg-config-paths.patch
|
|
];
|
|
|
|
nativeBuildInputs = [ cmake ];
|
|
propagatedBuildInputs = [ hiredis ];
|
|
|
|
cmakeFlags = [
|
|
"-DREDIS_PLUS_PLUS_BUILD_TEST=OFF"
|
|
] ++ lib.optionals (!enableShared) [
|
|
"-DREDIS_PLUS_PLUS_BUILD_SHARED=OFF"
|
|
] ++ lib.optionals (!enableStatic) [
|
|
"-DREDIS_PLUS_PLUS_BUILD_STATIC=OFF"
|
|
];
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/sewenew/redis-plus-plus";
|
|
description = "Redis client written in C++";
|
|
license = licenses.asl20;
|
|
platforms = platforms.unix;
|
|
maintainers = with maintainers; [ wheelsandmetal ];
|
|
};
|
|
}
|