571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
46 lines
1.3 KiB
Nix
46 lines
1.3 KiB
Nix
{ lib, fetchFromGitHub, buildGoModule }:
|
|
|
|
buildGoModule rec {
|
|
pname = "pg_featureserv";
|
|
version = "1.3.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "CrunchyData";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
sha256 = "sha256-GsloUZFgrOrJc23vKv+8iSeyIEKblaukPSCpZGRtSL4=";
|
|
};
|
|
|
|
vendorHash = "sha256-BHiEVyi3FXPovYy3iDP8q+y+LgfI4ElDPVZexd7nnuo=";
|
|
|
|
postPatch = ''
|
|
# fix default configuration file location
|
|
substituteInPlace \
|
|
internal/conf/config.go \
|
|
--replace-fail "viper.AddConfigPath(\"/etc\")" "viper.AddConfigPath(\"$out/share/config\")"
|
|
|
|
# fix assets location in configuration file
|
|
substituteInPlace \
|
|
config/pg_featureserv.toml.example \
|
|
--replace-fail "AssetsPath = \"./assets\"" "AssetsPath = \"$out/share/assets\""
|
|
'';
|
|
|
|
ldflags = [ "-s" "-w" "-X github.com/CrunchyData/pg_featureserv/conf.setVersion=${version}" ];
|
|
|
|
postInstall = ''
|
|
mkdir -p $out/share
|
|
cp -r assets $out/share
|
|
|
|
mkdir -p $out/share/config
|
|
cp config/pg_featureserv.toml.example $out/share/config/pg_featureserv.toml
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Lightweight RESTful Geospatial Feature Server for PostGIS in Go";
|
|
mainProgram = "pg_featureserv";
|
|
homepage = "https://github.com/CrunchyData/pg_featureserv";
|
|
license = licenses.asl20;
|
|
maintainers = teams.geospatial.members;
|
|
};
|
|
}
|