c8330c9972
My original commit was somewhat more tongue in cheek, but I think this time I'm going to be honest, rather than hiding behind humor. I'm angry that we as a community have reached a point where we're falling apart because people would rather accept sealioning and bad faith arguments that belong in a 2002 mailing list, not a 2024 software community. Every time I dare come back to the Nix community as a more active contributor it feels like we have a fresh wave of controversy that we don't ever heal from, everyone just moves on, more tired, and more broken than before. And now it's crossed a line. I'm out. I hope the community decides to actually try and heal. Tolerating the intolerant for too long has consequences - and the [paradox of tolerance](https://en.wikipedia.org/wiki/Paradox_of_tolerance) has come to its natural conclusion here. If it does heal, I'll be back with a vengeance, because it turns out replacing Nix is hard - emotionally and technically, and I'll miss it. ~Danielle (this commit+PR are not a place for useless debates.)
87 lines
2.1 KiB
Nix
87 lines
2.1 KiB
Nix
{ lib, buildGoModule, fetchFromGitHub, symlinkJoin, nixosTests, k3s }:
|
|
|
|
let
|
|
version = "3.5.13";
|
|
etcdSrcHash = "sha256-6dQXgM6VEWwv5CfHvxxPxdhMwNjFsinwhsbSqvQoDxI=";
|
|
etcdServerVendorHash = "sha256-PB4gACfeYhdOXYs0xbcq2CmSMJnf/ifX2U2DN6zfJ1o=";
|
|
etcdUtlVendorHash = "sha256-f23mn4zE6beM8yPSbs9gEEEifyF2D+CVKdlYwQtzAkQ=";
|
|
etcdCtlVendorHash = "sha256-gSlyhmLKarDwc+MhYuTeTqwj0wLiN6+k2bHEVVTkyPc=";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "etcd-io";
|
|
repo = "etcd";
|
|
rev = "v${version}";
|
|
hash = etcdSrcHash;
|
|
};
|
|
|
|
CGO_ENABLED = 0;
|
|
|
|
meta = with lib; {
|
|
description = "Distributed reliable key-value store for the most critical data of a distributed system";
|
|
license = licenses.asl20;
|
|
homepage = "https://etcd.io/";
|
|
maintainers = with maintainers; [ offline superherointj ];
|
|
platforms = platforms.darwin ++ platforms.linux;
|
|
};
|
|
|
|
etcdserver = buildGoModule rec {
|
|
pname = "etcdserver";
|
|
|
|
inherit CGO_ENABLED meta src version;
|
|
|
|
vendorHash = etcdServerVendorHash;
|
|
|
|
modRoot = "./server";
|
|
|
|
preInstall = ''
|
|
mv $GOPATH/bin/{server,etcd}
|
|
'';
|
|
|
|
# We set the GitSHA to `GitNotFound` to match official build scripts when
|
|
# git is unavailable. This is to avoid doing a full Git Checkout of etcd.
|
|
# User facing version numbers are still available in the binary, just not
|
|
# the sha it was built from.
|
|
ldflags = [ "-X go.etcd.io/etcd/api/v3/version.GitSHA=GitNotFound" ];
|
|
};
|
|
|
|
etcdutl = buildGoModule rec {
|
|
pname = "etcdutl";
|
|
|
|
inherit CGO_ENABLED meta src version;
|
|
|
|
vendorHash = etcdUtlVendorHash;
|
|
|
|
modRoot = "./etcdutl";
|
|
};
|
|
|
|
etcdctl = buildGoModule rec {
|
|
pname = "etcdctl";
|
|
|
|
inherit CGO_ENABLED meta src version;
|
|
|
|
vendorHash = etcdCtlVendorHash;
|
|
|
|
modRoot = "./etcdctl";
|
|
};
|
|
in
|
|
symlinkJoin {
|
|
name = "etcd-${version}";
|
|
|
|
inherit meta version;
|
|
|
|
passthru = {
|
|
inherit etcdserver etcdutl etcdctl;
|
|
tests = {
|
|
inherit (nixosTests) etcd etcd-cluster;
|
|
k3s = k3s.passthru.tests.etcd;
|
|
};
|
|
updateScript = ./update.sh;
|
|
};
|
|
|
|
paths = [
|
|
etcdserver
|
|
etcdutl
|
|
etcdctl
|
|
];
|
|
}
|