e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
64 lines
1.9 KiB
Nix
64 lines
1.9 KiB
Nix
{ lib, stdenv, fetchFromGitLab, getopt, lua, boost, libxcrypt, pkg-config, swig, perl, gcc }:
|
|
|
|
let
|
|
self = stdenv.mkDerivation rec {
|
|
pname = "highlight";
|
|
version = "4.12";
|
|
|
|
src = fetchFromGitLab {
|
|
owner = "saalen";
|
|
repo = "highlight";
|
|
rev = "v${version}";
|
|
hash = "sha256-TFMU9owxBGrrbatk7Jj9xP8OEJNjXnjbwnW6Xq34awI=";
|
|
};
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
nativeBuildInputs = [ pkg-config swig perl ]
|
|
++ lib.optional stdenv.hostPlatform.isDarwin gcc;
|
|
|
|
buildInputs = [ getopt lua boost libxcrypt ];
|
|
|
|
postPatch = ''
|
|
substituteInPlace src/makefile \
|
|
--replace "shell pkg-config" "shell $PKG_CONFIG"
|
|
substituteInPlace makefile \
|
|
--replace 'gzip' 'gzip -n'
|
|
'' + lib.optionalString stdenv.cc.isClang ''
|
|
substituteInPlace src/makefile \
|
|
--replace 'CXX=g++' 'CXX=clang++'
|
|
'';
|
|
|
|
preConfigure = ''
|
|
makeFlags="PREFIX=$out conf_dir=$out/etc/highlight/ CXX=$CXX AR=$AR"
|
|
'';
|
|
|
|
# This has to happen _before_ the main build because it does a
|
|
# `make clean' for some reason.
|
|
preBuild = lib.optionalString (!stdenv.hostPlatform.isDarwin) ''
|
|
make -C extras/swig $makeFlags perl
|
|
'';
|
|
|
|
postCheck = lib.optionalString (!stdenv.hostPlatform.isDarwin) ''
|
|
perl -Iextras/swig extras/swig/testmod.pl
|
|
'';
|
|
|
|
preInstall = lib.optionalString (!stdenv.hostPlatform.isDarwin) ''
|
|
mkdir -p $out/${perl.libPrefix}
|
|
install -m644 extras/swig/highlight.{so,pm} $out/${perl.libPrefix}
|
|
make -C extras/swig clean # Clean up intermediate files.
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Source code highlighting tool";
|
|
mainProgram = "highlight";
|
|
homepage = "http://www.andre-simon.de/doku/highlight/en/highlight.php";
|
|
platforms = platforms.unix;
|
|
maintainers = with maintainers; [ willibutz ];
|
|
};
|
|
};
|
|
|
|
in
|
|
if stdenv.hostPlatform.isDarwin then self
|
|
else perl.pkgs.toPerlModule self
|