e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
67 lines
1.8 KiB
Nix
67 lines
1.8 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, rustPlatform
|
|
, installShellFiles
|
|
, cmake
|
|
, git
|
|
, nixosTests
|
|
, Security
|
|
, Foundation
|
|
, Cocoa
|
|
}:
|
|
|
|
rustPlatform.buildRustPackage rec {
|
|
pname = "starship";
|
|
version = "1.20.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "starship";
|
|
repo = "starship";
|
|
rev = "v${version}";
|
|
hash = "sha256-Y7jX0XXrSMEex1HG0o69Q1rTtnFL0UuIEgfa1e7D1Nc=";
|
|
};
|
|
|
|
nativeBuildInputs = [ installShellFiles cmake ];
|
|
|
|
buildInputs = lib.optionals stdenv.hostPlatform.isDarwin [ Security Foundation Cocoa ];
|
|
|
|
NIX_LDFLAGS = lib.optionals (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isx86_64) [ "-framework" "AppKit" ];
|
|
|
|
# tries to access HOME only in aarch64-darwin environment when building mac-notification-sys
|
|
preBuild = lib.optionalString (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64) ''
|
|
export HOME=$TMPDIR
|
|
'';
|
|
|
|
postInstall = ''
|
|
presetdir=$out/share/starship/presets/
|
|
mkdir -p $presetdir
|
|
cp docs/public/presets/toml/*.toml $presetdir
|
|
'' + lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
|
|
installShellCompletion --cmd starship \
|
|
--bash <($out/bin/starship completions bash) \
|
|
--fish <($out/bin/starship completions fish) \
|
|
--zsh <($out/bin/starship completions zsh)
|
|
'';
|
|
|
|
cargoHash = "sha256-yJ32HFaRpujJ9mQa+07b5cQcl1ATO/56dpm1IeKcbzs=";
|
|
|
|
nativeCheckInputs = [ git ];
|
|
|
|
preCheck = ''
|
|
HOME=$TMPDIR
|
|
'';
|
|
|
|
passthru.tests = {
|
|
inherit (nixosTests) starship;
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Minimal, blazing fast, and extremely customizable prompt for any shell";
|
|
homepage = "https://starship.rs";
|
|
license = licenses.isc;
|
|
maintainers = with maintainers; [ danth davidtwco Br1ght0ne Frostman ];
|
|
mainProgram = "starship";
|
|
};
|
|
}
|