e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
68 lines
1.5 KiB
Nix
68 lines
1.5 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchurl
|
|
, fetchpatch
|
|
, pkg-config
|
|
, glib
|
|
, which
|
|
, bison
|
|
, nixosTests
|
|
, libnl
|
|
, linuxHeaders
|
|
, gnutls
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "nbd";
|
|
version = "3.25";
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/NetworkBlockDevice/nbd/releases/download/nbd-${version}/nbd-${version}.tar.xz";
|
|
hash = "sha256-9cj9D8tXsckmWU0OV/NWQy7ghni+8dQNCI8IMPDL3Qo=";
|
|
};
|
|
|
|
patches = [
|
|
# fix port setting from nbdtab
|
|
# https://github.com/NetworkBlockDevice/nbd/pull/154
|
|
(fetchpatch {
|
|
url = "https://github.com/NetworkBlockDevice/nbd/commit/915444bc0b8a931d32dfb755542f4bd1d37f1449.patch";
|
|
hash = "sha256-6z+c2cXhY92WPDqRO6AJ5BBf1N38yTgOE1foduIr5Dg=";
|
|
})
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
pkg-config
|
|
which
|
|
bison
|
|
];
|
|
|
|
buildInputs = [
|
|
glib
|
|
gnutls
|
|
] ++ lib.optionals stdenv.hostPlatform.isLinux [
|
|
libnl
|
|
linuxHeaders
|
|
];
|
|
|
|
configureFlags = [
|
|
"--sysconfdir=/etc"
|
|
];
|
|
|
|
# ISO C99 and later do not support implicit function declarations [-Wimplicit-function-declaration]
|
|
env.NIX_CFLAGS_COMPILE = lib.optionalString stdenv.cc.isClang "-Wno-error=implicit-function-declaration";
|
|
|
|
doCheck = !stdenv.hostPlatform.isDarwin;
|
|
|
|
passthru.tests = {
|
|
test = nixosTests.nbd;
|
|
};
|
|
|
|
meta = {
|
|
homepage = "https://nbd.sourceforge.io/";
|
|
description = "Map arbitrary files as block devices over the network";
|
|
license = lib.licenses.gpl2Only;
|
|
platforms = lib.platforms.unix;
|
|
maintainers = with lib.maintainers; [ nickcao ];
|
|
};
|
|
}
|