e0464e4788
In preparation for the deprecation of `stdenv.isX`. These shorthands are not conducive to cross-compilation because they hide the platforms. Darwin might get cross-compilation for which the continued usage of `stdenv.isDarwin` will get in the way One example of why this is bad and especially affects compiler packages https://www.github.com/NixOS/nixpkgs/pull/343059 There are too many files to go through manually but a treewide should get users thinking when they see a `hostPlatform.isX` in a place where it doesn't make sense. ``` fd --type f "\.nix" | xargs sd --fixed-strings "stdenv.is" "stdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenv'.is" "stdenv'.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "clangStdenv.is" "clangStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "gccStdenv.is" "gccStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "stdenvNoCC.is" "stdenvNoCC.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "inherit (stdenv) is" "inherit (stdenv.hostPlatform) is" fd --type f "\.nix" | xargs sd --fixed-strings "buildStdenv.is" "buildStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "effectiveStdenv.is" "effectiveStdenv.hostPlatform.is" fd --type f "\.nix" | xargs sd --fixed-strings "originalStdenv.is" "originalStdenv.hostPlatform.is" ```
64 lines
1.4 KiB
Nix
64 lines
1.4 KiB
Nix
{
|
|
lib,
|
|
overrideSDK,
|
|
stdenv,
|
|
darwin,
|
|
fetchFromGitHub,
|
|
testers,
|
|
nix-update-script,
|
|
}:
|
|
let
|
|
inherit (darwin.apple_sdk_11_0.frameworks) Carbon Cocoa;
|
|
|
|
stdenv' = if stdenv.hostPlatform.isDarwin then overrideSDK stdenv "11.0" else stdenv;
|
|
in
|
|
stdenv'.mkDerivation (finalAttrs: {
|
|
pname = "skhd";
|
|
version = "0.3.9";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "koekeishiya";
|
|
repo = "skhd";
|
|
rev = "v${finalAttrs.version}";
|
|
hash = "sha256-fnkWws/g4BdHKDRhqoCpdPFUavOHdk8R7h7H1dAdAYI=";
|
|
};
|
|
|
|
buildInputs = [
|
|
Carbon
|
|
Cocoa
|
|
];
|
|
|
|
makeFlags = [ "BUILD_PATH=$(out)/bin" ];
|
|
|
|
env.NIX_CFLAGS_COMPILE = "-Wno-error=implicit-function-declaration";
|
|
|
|
postInstall = ''
|
|
mkdir -p $out/Library/LaunchDaemons
|
|
cp ${./org.nixos.skhd.plist} $out/Library/LaunchDaemons/org.nixos.skhd.plist
|
|
substituteInPlace $out/Library/LaunchDaemons/org.nixos.skhd.plist --subst-var out
|
|
'';
|
|
|
|
passthru = {
|
|
tests.version = testers.testVersion {
|
|
package = finalAttrs.finalPackage;
|
|
version = "skhd-v${finalAttrs.version}";
|
|
};
|
|
|
|
updateScript = nix-update-script { };
|
|
};
|
|
|
|
meta = {
|
|
description = "Simple hotkey daemon for macOS";
|
|
homepage = "https://github.com/koekeishiya/skhd";
|
|
license = lib.licenses.mit;
|
|
mainProgram = "skhd";
|
|
maintainers = with lib.maintainers; [
|
|
cmacrae
|
|
lnl7
|
|
periklis
|
|
khaneliman
|
|
];
|
|
platforms = lib.platforms.darwin;
|
|
};
|
|
})
|