092b6b68a0
gnupg 2.1.14 fails to compile under OS X due to a missing -lintl flag [1]. This was fixed in commit c49c43d7 in the gnupg repository [2], which adds the flag to Makefile.am. This commit adds the flag to Makefile.in. [1] https://lists.gnupg.org/pipermail/gnupg-devel/2016-July/031354.html [2] https://lists.gnupg.org/pipermail/gnupg-devel/2016-July/031362.html Fixes #17617.
48 lines
1.4 KiB
Nix
48 lines
1.4 KiB
Nix
{ fetchurl, stdenv, pkgconfig, libgcrypt, libassuan, libksba, libiconv, npth
|
|
, gettext, texinfo, pcsclite
|
|
|
|
# Each of the dependencies below are optional.
|
|
# Gnupg can be built without them at the cost of reduced functionality.
|
|
, pinentry ? null, x11Support ? true
|
|
, adns ? null, gnutls ? null, libusb ? null, openldap ? null
|
|
, readline ? null, zlib ? null, bzip2 ? null
|
|
}:
|
|
|
|
with stdenv.lib;
|
|
|
|
assert x11Support -> pinentry != null;
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "gnupg-${version}";
|
|
|
|
version = "2.1.14";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://gnupg/gnupg/${name}.tar.bz2";
|
|
sha256 = "0hmsiscpdpdqd8kcjpzkz2gzcc3cnrvswk9p1jzi4sivd7lxwl4l";
|
|
};
|
|
|
|
buildInputs = [
|
|
pkgconfig libgcrypt libassuan libksba libiconv npth gettext texinfo
|
|
readline libusb gnutls adns openldap zlib bzip2
|
|
];
|
|
|
|
patches = [ ./fix-gpgsm-linking.patch ];
|
|
|
|
postPatch = stdenv.lib.optionalString stdenv.isLinux ''
|
|
sed -i 's,"libpcsclite\.so[^"]*","${pcsclite}/lib/libpcsclite.so",g' scd/scdaemon.c
|
|
''; #" fix Emacs syntax highlighting :-(
|
|
|
|
configureFlags = optional x11Support "--with-pinentry-pgm=${pinentry}/bin/pinentry";
|
|
|
|
postConfigure = "substituteAllInPlace tools/gpgkey2ssh.c";
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = http://gnupg.org;
|
|
description = "A complete and free implementation of the OpenPGP standard";
|
|
license = licenses.gpl3Plus;
|
|
maintainers = with maintainers; [ wkennington peti fpletz vrthra ];
|
|
platforms = platforms.all;
|
|
};
|
|
}
|