571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
44 lines
1.2 KiB
Nix
44 lines
1.2 KiB
Nix
{ lib, buildGoModule, fetchFromGitHub, installShellFiles, testers, fioctl }:
|
|
|
|
buildGoModule rec {
|
|
pname = "fioctl";
|
|
version = "0.42";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "foundriesio";
|
|
repo = "fioctl";
|
|
rev = "v${version}";
|
|
sha256 = "sha256-UqUr57D5nZh+zanzCmxujLbA8eICKx0NUlP78YH8x/Q=";
|
|
};
|
|
|
|
vendorHash = "sha256-A5buz9JOAiXx9X4qmi7mTMJiy/E6XBaFlG/sXOG5AKw=";
|
|
|
|
ldflags = [
|
|
"-s" "-w"
|
|
"-X github.com/foundriesio/fioctl/subcommands/version.Commit=${src.rev}"
|
|
];
|
|
|
|
nativeBuildInputs = [ installShellFiles ];
|
|
|
|
postInstall = ''
|
|
installShellCompletion --cmd fioctl \
|
|
--bash <($out/bin/fioctl completion bash) \
|
|
--fish <($out/bin/fioctl completion fish) \
|
|
--zsh <($out/bin/fioctl completion zsh)
|
|
'';
|
|
|
|
passthru.tests.version = testers.testVersion {
|
|
package = fioctl;
|
|
command = "HOME=$(mktemp -d) fioctl version";
|
|
version = "v${version}";
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Simple CLI to manage your Foundries Factory";
|
|
homepage = "https://github.com/foundriesio/fioctl";
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [ nixinator matthewcroughan ];
|
|
mainProgram = "fioctl";
|
|
};
|
|
}
|