From f5a0d549d3f888cdcc3cc732d45064ec99d2a97a Mon Sep 17 00:00:00 2001
From: Nikolay Korotkiy <sikmir@disroot.org>
Date: Fri, 21 Jul 2023 21:48:10 +0400
Subject: [PATCH] knxd: init at 0.14.59

---
 pkgs/servers/knxd/default.nix   | 54 +++++++++++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix |  2 ++
 2 files changed, 56 insertions(+)
 create mode 100644 pkgs/servers/knxd/default.nix

diff --git a/pkgs/servers/knxd/default.nix b/pkgs/servers/knxd/default.nix
new file mode 100644
index 000000000000..ad484a181c4e
--- /dev/null
+++ b/pkgs/servers/knxd/default.nix
@@ -0,0 +1,54 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, autoreconfHook
+, pkg-config
+, indent
+, perl
+, argp-standalone
+, fmt_9
+, libev
+, withSystemd ? lib.meta.availableOn stdenv.hostPlatform systemd, systemd
+, withUsb ? stdenv.isLinux, libusb1
+}:
+
+stdenv.mkDerivation rec {
+  pname = "knxd";
+  version = "0.14.59";
+
+  src = fetchFromGitHub {
+    owner = "knxd";
+    repo = "knxd";
+    rev = version;
+    hash = "sha256-m3119aD23XTViQJ2s7hwnJZ1ct4bcEFWuyUQajmqySQ=";
+  };
+
+  postPatch = ''
+    sed -i '2i echo ${version}; exit' tools/version.sh
+    sed -i '2i exit' tools/get_libfmt
+  '';
+
+  nativeBuildInputs = [ autoreconfHook pkg-config indent perl ];
+
+  buildInputs = [ fmt_9 libev ]
+    ++ lib.optional withSystemd systemd
+    ++ lib.optional withUsb libusb1
+    ++ lib.optional stdenv.isDarwin argp-standalone;
+
+  configureFlags = lib.optional (!withSystemd) "--disable-systemd"
+    ++ lib.optional (!withUsb) "--disable-usb";
+
+  installFlags = lib.optionals withSystemd [
+    "systemdsystemunitdir=$(out)/lib/systemd/system"
+    "systemdsysusersdir=$(out)/lib/sysusers.d"
+  ];
+
+  meta = with lib; {
+    description = "Advanced router/gateway for KNX";
+    homepage = "https://github.com/knxd/knxd";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ sikmir ];
+    platforms = platforms.unix;
+  };
+}
+
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 0dc16d75b44c..2b11e5e17149 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -5553,6 +5553,8 @@ with pkgs;
 
   klog = qt5.callPackage ../applications/radio/klog { };
 
+  knxd = callPackage ../servers/knxd { };
+
   komga = callPackage ../servers/komga { };
 
   komorebi = callPackage ../applications/graphics/komorebi { };