Merge pull request #321575 from fufexan/hyprland

hyprlandPlugins: init upstream hyprland-plugins at 0.41.1, hy3: 0.41.0 -> 0.41.1

pkgs/applications/window-managers/hyprwm/hyprland-plugins/default.nix

@@ -1,50 +1,35 @@
-{ lib
-, callPackage
-, pkg-config
-, stdenv
-, hyprland
+{
+  lib,
+  callPackage,
+  pkg-config,
+  stdenv,
+  hyprland,
 }:
 let
-  mkHyprlandPlugin = hyprland:
+  mkHyprlandPlugin =
+    hyprland:
     args@{ pluginName, ... }:
-    stdenv.mkDerivation (args // {
-      pname = "${pluginName}";
-      nativeBuildInputs = [ pkg-config ] ++ args.nativeBuildInputs or [ ];
-      buildInputs = [ hyprland ]
-        ++ hyprland.buildInputs
-        ++ (args.buildInputs or [ ]);
-      meta = args.meta // {
-        description = args.meta.description or "";
-        longDescription = (args.meta.longDescription or "") +
-          "\n\nPlugins can be installed via a plugin entry in the Hyprland NixOS or Home Manager options.";
-      };
-    });
-
-  plugins = {
-    hy3 = { fetchFromGitHub, cmake, hyprland }:
-      mkHyprlandPlugin hyprland rec {
-        pluginName = "hy3";
-        version = "0.41.0";
-
-        src = fetchFromGitHub {
-          owner = "outfoxxed";
-          repo = "hy3";
-          rev = "hl${version}";
-          hash = "sha256-gEEWWlQRvejSR2RRg78Lubz6siIgknqj6CslveyyIP4=";
+    stdenv.mkDerivation (
+      args
+      // {
+        pname = "${pluginName}";
+        nativeBuildInputs = [ pkg-config ] ++ args.nativeBuildInputs or [ ];
+        buildInputs = [ hyprland ] ++ hyprland.buildInputs ++ (args.buildInputs or [ ]);
+        meta = args.meta // {
+          description = args.meta.description or "";
+          longDescription =
+            (args.meta.longDescription or "")
+            + "\n\nPlugins can be installed via a plugin entry in the Hyprland NixOS or Home Manager options.";
         };
+      }
+    );
 
-        nativeBuildInputs = [ cmake ];
-
-        dontStrip = true;
-
-        meta = {
-          homepage = "https://github.com/outfoxxed/hy3";
-          description = "Hyprland plugin for an i3 / sway like manual tiling layout";
-          license = lib.licenses.gpl3;
-          platforms = lib.platforms.linux;
-          maintainers = with lib.maintainers; [ aacebedo ];
-        };
-      };
-  };
+  plugins = lib.mergeAttrsList [
+    { hy3 = import ./hy3.nix; }
+    (import ./hyprland-plugins.nix)
+  ];
 in
-(lib.mapAttrs (name: plugin: callPackage plugin { }) plugins) // { inherit mkHyprlandPlugin; }
+(lib.mapAttrs (name: plugin: callPackage plugin { inherit mkHyprlandPlugin; }) plugins)
+// {
+  inherit mkHyprlandPlugin;
+}

pkgs/applications/window-managers/hyprwm/hyprland-plugins/hy3.nix

@@ -0,0 +1,30 @@
+{
+  lib,
+  cmake,
+  fetchFromGitHub,
+  hyprland,
+  mkHyprlandPlugin,
+}:
+mkHyprlandPlugin hyprland rec {
+  pluginName = "hy3";
+  version = "0.41.1";
+
+  src = fetchFromGitHub {
+    owner = "outfoxxed";
+    repo = "hy3";
+    rev = "hl${version}";
+    hash = "sha256-bRLI+zgfT31LCMW4Pf701ZZx2oFeXoBu1BfYQjX6MPc=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+
+  dontStrip = true;
+
+  meta = {
+    homepage = "https://github.com/outfoxxed/hy3";
+    description = "Hyprland plugin for an i3 / sway like manual tiling layout";
+    license = lib.licenses.gpl3;
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [ aacebedo ];
+  };
+}

pkgs/applications/window-managers/hyprwm/hyprland-plugins/hyprland-plugins.nix

@@ -0,0 +1,51 @@
+let
+  # shared src for upstream hyprland-plugins repo
+  # function generating derivations for all plugins in hyprland-plugins
+  hyprland-plugins =
+    builtins.mapAttrs
+      (
+        name: description:
+        (
+          {
+            lib,
+            cmake,
+            fetchFromGitHub,
+            hyprland,
+            mkHyprlandPlugin,
+          }:
+          let
+            version = "0.41.1";
+
+            hyprland-plugins-src = fetchFromGitHub {
+              owner = "hyprwm";
+              repo = "hyprland-plugins";
+              rev = "v${version}";
+              hash = "sha256-Bw3JRBUZg2kmDwxa/UHvD//gGcNjbftTj2MSeLvx1q8=";
+            };
+          in
+          mkHyprlandPlugin hyprland {
+            pluginName = name;
+            inherit version;
+
+            src = "${hyprland-plugins-src}/${name}";
+            nativeBuildInputs = [ cmake ];
+            meta = {
+              homepage = "https://github.com/hyprwm/hyprland-plugins";
+              description = "Hyprland ${description} plugin";
+              license = lib.licenses.bsd3;
+              maintainers = with lib.maintainers; [ fufexan ];
+              platforms = lib.platforms.linux;
+            };
+          }
+        )
+      )
+      {
+        borders-plus-plus = "multiple borders";
+        csgo-vulkan-fix = "CS:GO/CS2 Vulkan fix";
+        hyprbars = "window title";
+        hyprexpo = "workspaces overview";
+        hyprtrails = "smooth trails behind moving windows";
+        hyprwinwrap = "xwinwrap-like";
+      };
+in
+hyprland-plugins