From e2e2443f5c2760db73ad69f5475c89af1b8564a8 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?St=C3=A9phan=20Kochen?= <git@stephank.nl>
Date: Tue, 11 Jul 2023 13:41:23 +0200
Subject: [PATCH] mailpit: init at 1.7.1

---
 pkgs/servers/mail/mailpit/default.nix | 46 +++++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix       |  4 +++
 2 files changed, 50 insertions(+)
 create mode 100644 pkgs/servers/mail/mailpit/default.nix

diff --git a/pkgs/servers/mail/mailpit/default.nix b/pkgs/servers/mail/mailpit/default.nix
new file mode 100644
index 000000000000..aa7a21371180
--- /dev/null
+++ b/pkgs/servers/mail/mailpit/default.nix
@@ -0,0 +1,46 @@
+{ lib
+, buildGoModule
+, nodejs
+, python3
+, libtool
+, npmHooks
+, fetchFromGitHub
+, fetchNpmDeps
+}:
+
+buildGoModule rec {
+  pname = "mailpit";
+  version = "1.7.1";
+
+  src = fetchFromGitHub {
+    owner = "axllent";
+    repo = "mailpit";
+    rev = "v${version}";
+    hash = "sha256-jT9QE0ikp9cJlT8qtfPPjKOUuqWyQk94D3UbkyaGXa8=";
+  };
+
+  vendorHash = "sha256-XBYIO7fdo5EahJB7EcAuY9SGKZb8dsvoJHp/D5LO5Qo=";
+
+  npmDeps = fetchNpmDeps {
+    inherit src;
+    hash = "sha256-6VCs8125fTJkZW+eZgK56j7ccK8tcGhIXiq2HkYp4XM=";
+  };
+
+  nativeBuildInputs = [ nodejs python3 libtool npmHooks.npmConfigHook ];
+
+  preBuild = ''
+    npm run package
+  '';
+
+  CGO_ENABLED = 0;
+
+  ldflags = [ "-s" "-w" "-X github.com/axllent/mailpit/config.Version=${version}" ];
+
+  meta = with lib; {
+    description = "An email and SMTP testing tool with API for developers";
+    homepage = "https://github.com/axllent/mailpit";
+    changelog = "https://github.com/axllent/mailpit/releases/tag/v${version}";
+    maintainers = with maintainers; [ stephank ];
+    license = licenses.mit;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 37f3bfb16be2..64dc03f5745c 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -10213,6 +10213,10 @@ with pkgs;
   );
   bubblemail = callPackage ../applications/networking/mailreaders/bubblemail { };
 
+  mailpit = callPackage ../servers/mail/mailpit {
+    libtool = if stdenv.isDarwin then darwin.cctools else libtool;
+  };
+
   mailsend = callPackage ../tools/networking/mailsend { };
 
   mailutils = callPackage ../tools/networking/mailutils {