Merge pull request #178020 from fabaff/amoco

amoco: init at 2.9.8

pkgs/development/python-modules/crysp/default.nix

@@ -0,0 +1,48 @@
+{ lib
+, buildPythonPackage
+, fetchFromGitHub
+, grandalf
+, matplotlib
+, pytestCheckHook
+, pythonOlder
+}:
+
+buildPythonPackage rec {
+  pname = "crysp";
+  version = "1.2";
+  format = "setuptools";
+
+  disabled = pythonOlder "3.7";
+
+  src = fetchFromGitHub {
+    owner = "bdcht";
+    repo = pname;
+    rev = "v${version}";
+    hash = "sha256-51SKS6OOXIFT1L3YICR6a4QGSz/rbB8V+Z0u0jMO474=";
+  };
+
+  propagatedBuildInputs = [
+    grandalf
+    matplotlib
+  ];
+
+  checkInputs = [
+    pytestCheckHook
+  ];
+
+  postPatch = ''
+    substituteInPlace setup.py \
+      --replace "'pytest-runner'," ""
+  '';
+
+  pythonImportsCheck = [
+    "crysp"
+  ];
+
+  meta = with lib; {
+    description = "Module that provides crypto-related facilities";
+    homepage = "https://github.com/bdcht/crysp";
+    license = with licenses; [ gpl2Only ];
+    maintainers = with maintainers; [ fab ];
+  };
+}

pkgs/tools/security/amoco/default.nix

@@ -0,0 +1,72 @@
+{ lib
+, fetchFromGitHub
+, python3
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "amoco";
+  version = "2.9.8";
+  format = "setuptools";
+
+  src = fetchFromGitHub {
+    owner = "bdcht";
+    repo = pname;
+    rev = "v${version}";
+    hash = "sha256-3+1ssFyU7SKFJgDYBQY0kVjmTHOD71D2AjnH+4bfLXo=";
+  };
+
+  nativeBuildInputs = with python3.pkgs; [
+    pythonRelaxDepsHook
+  ];
+
+  propagatedBuildInputs = with python3.pkgs; [
+    blessed
+    click
+    crysp
+    grandalf
+    pyparsing
+    tqdm
+    traitlets
+  ];
+
+  passthru.optional-dependencies = {
+    app = with python3.pkgs; [
+      # ccrawl
+      ipython
+      prompt-toolkit
+      pygments
+      # pyside6
+      z3
+    ];
+  };
+
+  checkInputs = with python3.pkgs; [
+    pytestCheckHook
+  ];
+
+  postPatch = ''
+    substituteInPlace setup.py \
+      --replace "'pytest-runner'," ""
+  '';
+
+  pythonRelaxDeps = [
+    "grandalf"
+    "crysp"
+  ];
+
+  pythonImportsCheck = [
+    "amoco"
+  ];
+
+  disabledTests = [
+    # AttributeError: 'str' object has no attribute '__dict__'
+    "test_func"
+  ];
+
+  meta = with lib; {
+    description = "Tool for analysing binaries";
+    homepage = "https://github.com/bdcht/amoco";
+    license = licenses.gpl2Only;
+    maintainers = with maintainers; [ fab ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -2853,6 +2853,8 @@ with pkgs;
     inherit (androidenv.androidPkgs_9_0) platform-tools;
   };
 
+  amoco = callPackage ../tools/security/amoco {};
+
   anbox = callPackage ../os-specific/linux/anbox { };
 
   androidenv = callPackage ../development/mobile/androidenv {

pkgs/top-level/python-packages.nix

@@ -2146,6 +2146,8 @@ in {
 
   cryptoparser = callPackage ../development/python-modules/cryptoparser { };
 
+  crysp = callPackage ../development/python-modules/crysp { };
+
   crytic-compile = callPackage ../development/python-modules/crytic-compile { };
 
   csrmesh  = callPackage ../development/python-modules/csrmesh { };