From b4fbaae278aab14ed2c69d4f96d2f6a35af1b3e3 Mon Sep 17 00:00:00 2001
From: natsukium <tomoya.otabi@gmail.com>
Date: Sun, 18 Aug 2024 11:10:01 +0900
Subject: [PATCH] andi: init at 0.14
Efficient Estimation of Evolutionary Distances
https://github.com/evolbioinf/andi
---
pkgs/by-name/an/andi/package.nix | 52 ++++++++++++++++++++++++++++++++
1 file changed, 52 insertions(+)
create mode 100644 pkgs/by-name/an/andi/package.nix
diff --git a/pkgs/by-name/an/andi/package.nix b/pkgs/by-name/an/andi/package.nix
new file mode 100644
index 000000000000..85b9cbdf5a13
--- /dev/null
+++ b/pkgs/by-name/an/andi/package.nix
@@ -0,0 +1,52 @@
+{
+ lib,
+ stdenv,
+ fetchFromGitHub,
+ autoreconfHook,
+ pkg-config,
+ glib,
+ gsl,
+ libdivsufsort,
+ llvmPackages,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+ pname = "andi";
+ version = "0.14";
+
+ src = fetchFromGitHub {
+ owner = "evolbioinf";
+ repo = "andi";
+ rev = "refs/tags/v${finalAttrs.version}";
+ hash = "sha256-tjQ9exFyqu/xnbUGpF6k0kE5C1D93kISjRErwHfjW9E=";
+ };
+
+ nativeBuildInputs = [
+ autoreconfHook
+ pkg-config
+ ];
+
+ buildInputs = [
+ gsl
+ libdivsufsort
+ ] ++ lib.optionals stdenv.hostPlatform.isDarwin [ llvmPackages.openmp ];
+
+ configureFlags = [ (lib.enableFeature finalAttrs.finalPackage.doCheck "unit-tests") ];
+
+ nativeCheckInputs = [ glib ];
+
+ doCheck = true;
+
+ preCheck = ''
+ patchShebangs ./test
+ '';
+
+ meta = {
+ description = "Efficient Estimation of Evolutionary Distances";
+ homepage = "https://github.com/evolbioinf/andi";
+ license = lib.licenses.gpl3Plus;
+ maintainers = with lib.maintainers; [ natsukium ];
+ mainProgram = "andi";
+ platforms = lib.platforms.all;
+ };
+})