Merge pull request #313623 from Aleksanaa/plattenalbum

plattenalbum: 1.11.0 -> 2.1.0; renamed from mpdevil

pkgs/applications/audio/mpdevil/default.nix

@@ -1,56 +0,0 @@
-{ lib, fetchFromGitHub
-, pkg-config, meson ,ninja
-, python3Packages
-, gdk-pixbuf, glib, gobject-introspection, gtk3
-, libnotify
-, wrapGAppsHook3 }:
-
-python3Packages.buildPythonApplication rec {
-  pname = "mpdevil";
-  version = "1.11.0";
-
-  src = fetchFromGitHub {
-    owner = "SoongNoonien";
-    repo = pname;
-    rev = "refs/tags/v${version}";
-    sha256 = "sha256-ooNZSsVtIeueqgj9hR9OZp08qm8gGokiq8IU3U/ZV5w=";
-  };
-
-  format = "other";
-
-  nativeBuildInputs = [
-    glib.dev gobject-introspection gtk3 pkg-config meson ninja wrapGAppsHook3
-  ];
-
-  buildInputs = [
-    gdk-pixbuf glib libnotify
-  ];
-
-  propagatedBuildInputs = with python3Packages; [
-    beautifulsoup4 distutils-extra mpd2 notify-py pygobject3 requests
-  ];
-
-  postInstall = ''
-    glib-compile-schemas $out/share/glib-2.0/schemas
-  '';
-
-  preFixup = ''
-    makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
-  '';
-
-  # Prevent double wrapping.
-  dontWrapGApps = true;
-  # Otherwise wrapGAppsHook3 do not pick up the dependencies correctly.
-  strictDeps = false;
-  # There aren't any checks.
-  doCheck = false;
-
-  meta = with lib; {
-    description = "A simple music browser for MPD";
-    homepage = "https://github.com/SoongNoonien/mpdevil";
-    license = licenses.gpl3Plus;
-    platforms = platforms.linux;
-    maintainers = with maintainers; [ apfelkuchen6 ];
-    mainProgram = "mpdevil";
-  };
-}

pkgs/by-name/pl/plattenalbum/package.nix

@@ -0,0 +1,60 @@
+{
+  lib,
+  python3Packages,
+  fetchFromGitHub,
+  meson,
+  ninja,
+  pkg-config,
+  gobject-introspection,
+  wrapGAppsHook4,
+  desktop-file-utils,
+  libadwaita,
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "plattenalbum";
+  version = "2.1.0";
+  pyproject = false;
+
+  src = fetchFromGitHub {
+    owner = "SoongNoonien";
+    repo = "plattenalbum";
+    rev = "v${version}";
+    hash = "sha256-vRBlShbNuPpL29huhzYSuUcMJmSLljO4nc6cSAp3NB4=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    gobject-introspection
+    wrapGAppsHook4
+    desktop-file-utils
+  ];
+
+  buildInputs = [ libadwaita ];
+
+  dependencies = with python3Packages; [
+    pygobject3
+    mpd2
+  ];
+
+  dontWrapGApps = true;
+
+  preFixup = ''
+    makeWrapperArgs+=(''${gappsWrapperArgs[@]})
+  '';
+
+  meta = {
+    description = "A client for the Music Player Daemon (originally named mpdevil)";
+    homepage = "https://github.com/SoongNoonien/plattenalbum";
+    changelog = "https://github.com/SoongNoonien/plattenalbum/releases/tag/v${version}";
+    license = with lib.licenses; [
+      gpl3Only
+      cc0
+    ];
+    mainProgram = "plattenalbum";
+    maintainers = with lib.maintainers; [ aleksana ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/top-level/aliases.nix

@@ -834,6 +834,7 @@ mapAliases ({
   mozart = throw "'mozart' has been renamed to/replaced by 'mozart2-binary'"; # Converted to throw 2023-09-10
   mpc_cli = mpc-cli; # moved from top-level 2022-01-24
   mpd_clientlib = libmpdclient; # Added 2021-02-11
+  mpdevil = plattenalbum; # Added 2024-05-22
   mpg321 = throw "'mpg321' has been removed due to it being unmaintained by upstream. Consider using mpg123 instead."; # Added 2024-05-10
   mumble_git = throw "'mumble_git' has been renamed to/replaced by 'pkgs.mumble'"; # Converted to throw 2023-09-10
   murmur_git = throw "'murmur_git' has been renamed to/replaced by 'pkgs.murmur'"; # Converted to throw 2023-09-10

pkgs/top-level/all-packages.nix

@@ -3928,8 +3928,6 @@ with pkgs;
 
   mobilecoin-wallet = callPackage ../applications/misc/mobilecoin-wallet { };
 
-  mpdevil = callPackage ../applications/audio/mpdevil { };
-
   pacparser = callPackage ../tools/networking/pacparser { };
 
   pairdrop = callPackage ../applications/misc/pairdrop { };