nodejs-5_0: add package

pkgs/development/web/nodejs/v5_0.nix

@@ -0,0 +1,62 @@
+{ stdenv, fetchurl, openssl, python, zlib, libuv, v8, utillinux, http-parser
+, pkgconfig, runCommand, which, libtool
+}:
+
+# nodejs 5.0.0 can't be built on armv5tel. Armv6 with FPU, minimum I think.
+# Related post: http://zo0ok.com/techfindings/archives/1820
+assert stdenv.system != "armv5tel-linux";
+
+let
+  version = "5.0.0";
+
+  deps = {
+    inherit openssl zlib libuv;
+
+    # disabled system v8 because v8 3.14 no longer receives security fixes
+    # we fall back to nodejs' internal v8 copy which receives backports for now
+    # inherit v8
+  } // (stdenv.lib.optionalAttrs (!stdenv.isDarwin) {
+    inherit http-parser;
+  });
+
+  sharedConfigureFlags = name: [
+    "--shared-${name}"
+    "--shared-${name}-includes=${builtins.getAttr name deps}/include"
+    "--shared-${name}-libpath=${builtins.getAttr name deps}/lib"
+  ];
+
+  inherit (stdenv.lib) concatMap optional optionals maintainers licenses platforms;
+in stdenv.mkDerivation {
+  name = "nodejs-${version}";
+
+  src = fetchurl {
+    url = "http://nodejs.org/dist/v${version}/node-v${version}.tar.gz";
+    sha256 = "1x6dmk78k4cpdzvxi8390w2w0pvkb6bc1rc64l5a5rks0ri9d3b9";
+  };
+
+  configureFlags = concatMap sharedConfigureFlags (builtins.attrNames deps) ++ [ "--without-dtrace" ];
+  dontDisableStatic = true;
+  prePatch = ''
+    patchShebangs .
+    sed -i 's/raise.*No Xcode or CLT version detected.*/version = "7.0.0"/' tools/gyp/pylib/gyp/xcode_emulation.py
+  '';
+
+  patches = stdenv.lib.optionals stdenv.isDarwin [ ./no-xcode.patch ./pkg-libpath.patch ];
+
+  buildInputs = [ python which zlib libuv openssl python ]
+    ++ optionals stdenv.isLinux [ utillinux http-parser ]
+    ++ optionals stdenv.isDarwin [ pkgconfig openssl libtool ];
+  setupHook = ./setup-hook.sh;
+
+  enableParallelBuilding = true;
+
+  passthru.interpreterName = "nodejs";
+
+  meta = {
+    description = "Event-driven I/O framework for the V8 JavaScript engine";
+    homepage = http://nodejs.org;
+    license = licenses.mit;
+    maintainers = [ maintainers.goibhniu maintainers.havvy ];
+    platforms = platforms.linux ++ platforms.darwin;
+  };
+}

pkgs/top-level/all-packages.nix

@@ -2048,6 +2048,11 @@ let
 
   ninka = callPackage ../development/tools/misc/ninka { };
 
+  nodejs-5_0 = callPackage ../development/web/nodejs/v5_0.nix {
+    libtool = darwin.cctools;
+    openssl = openssl_1_0_2;
+  };
+
   nodejs-4_2 = callPackage ../development/web/nodejs {
     libtool = darwin.cctools;
     openssl = openssl_1_0_2;