From 9ac50cec5033b9c35fb29909624726b8c62d4bb9 Mon Sep 17 00:00:00 2001
From: Daniel Bulant <danbulant@gmail.com>
Date: Sun, 4 Aug 2024 11:46:20 +0200
Subject: [PATCH] udev-block-notify: init at 0.7.11

---
 pkgs/by-name/ud/udev-block-notify/package.nix | 54 +++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 pkgs/by-name/ud/udev-block-notify/package.nix

diff --git a/pkgs/by-name/ud/udev-block-notify/package.nix b/pkgs/by-name/ud/udev-block-notify/package.nix
new file mode 100644
index 000000000000..028d4742c19f
--- /dev/null
+++ b/pkgs/by-name/ud/udev-block-notify/package.nix
@@ -0,0 +1,54 @@
+{
+  stdenv,
+  fetchFromGitHub,
+  multimarkdown,
+  libnotify,
+  udev,
+  systemdLibs,
+  glib,
+  pkg-config,
+  lib,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "udev-block-notify";
+  version = "0.7.11";
+
+  src = fetchFromGitHub {
+    owner = "eworm-de";
+    repo = "udev-block-notify";
+    rev = "refs/tags/${finalAttrs.version}";
+    hash = "sha256-A0uhfb2mEAAJgxRkv+MWTk/9oFiz3r7deAlu1Kpk+CI=";
+  };
+
+  nativeBuildInputs = [
+    multimarkdown
+    pkg-config
+  ];
+  buildInputs = [
+    libnotify
+    udev
+    systemdLibs
+    glib
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    substituteInPlace systemd/udev-block-notify.service \
+      --replace-fail '/usr/bin/udev-block-notify' "$out/bin/udev-block-notify"
+
+    install -D -m0755 udev-block-notify $out/bin/udev-block-notify
+    install -D -m0644 systemd/udev-block-notify.service $out/lib/systemd/user/udev-block-notify.service
+
+    runHook postInstall
+  '';
+
+  meta = {
+    homepage = "https://github.com/eworm-de/udev-block-notify";
+    description = "Notify about udev block events";
+    mainProgram = "udev-block-notify";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ danbulant ];
+    platforms = lib.platforms.linux;
+  };
+})