npiet: cleanup

- Move to pkgs/by-name
- Format
- Use `finalAttrs` instead of `rec` for passing the `version` to `fetchurl`
- Use `hash` instead of `sha256` for `fetchurl`
- Use `--replace-fail` instead of `--replace` for `substituteInPlace`
- Add `strictDeps = true`
- Use `lib` directly in `meta` instead of using `with lib;`
- Add `meta.changelog`
- Add `meta.mainProgram`

pkgs/by-name/np/npiet/package.nix

@@ -1,23 +1,28 @@
-{ lib
-, stdenv
-, fetchurl
-, gd
-, giflib
-, groff
-, libpng
-, tk
+{
+  lib,
+  stdenv,
+  fetchurl,
+  gd,
+  giflib,
+  groff,
+  libpng,
+  tk,
 }:
 
-stdenv.mkDerivation rec {
+stdenv.mkDerivation (finalAttrs: {
   pname = "npiet";
   version = "1.3f";
 
   src = fetchurl {
-    url = "https://www.bertnase.de/npiet/npiet-${version}.tar.gz";
-    sha256 = "sha256-Le2FYGKr1zWZ6F4edozmvGC6LbItx9aptidj3KBLhVo=";
+    url = "https://www.bertnase.de/npiet/npiet-${finalAttrs.version}.tar.gz";
+    hash = "sha256-Le2FYGKr1zWZ6F4edozmvGC6LbItx9aptidj3KBLhVo=";
   };
 
-  buildInputs = [ gd giflib libpng ];
+  buildInputs = [
+    gd
+    giflib
+    libpng
+  ];
 
   nativeBuildInputs = [ groff ];
 
@@ -25,21 +30,25 @@ stdenv.mkDerivation rec {
     # malloc.h is not needed because stdlib.h is already included.
     # On macOS, malloc.h does not even exist, resulting in an error.
     substituteInPlace npiet-foogol.c \
-        --replace '#include <malloc.h>' ""
+      --replace-fail '#include <malloc.h>' ""
 
     substituteInPlace npietedit \
-        --replace 'exec wish' 'exec ${tk}/bin/wish'
+      --replace-fail 'exec wish' 'exec ${tk}/bin/wish'
   '';
 
-  meta = with lib; {
+  strictDeps = true;
+
+  meta = {
     description = "Interpreter for piet programs. Also includes npietedit and npiet-foogol";
     longDescription = ''
       npiet is an interpreter for the piet programming language.
       Instead of text, piet programs are pictures. Commands are determined based on changes in color.
     '';
     homepage = "https://www.bertnase.de/npiet/";
-    license = licenses.gpl2Only;
-    platforms = platforms.unix;
-    maintainers = with maintainers; [ Luflosi ];
+    changelog = "https://www.bertnase.de/npiet/ChangeLog";
+    license = lib.licenses.gpl2Only;
+    platforms = lib.platforms.unix;
+    mainProgram = "npiet";
+    maintainers = with lib.maintainers; [ Luflosi ];
   };
-}
+})

pkgs/top-level/all-packages.nix

@@ -10833,8 +10833,6 @@ with pkgs;
 
   npapi_sdk = callPackage ../development/libraries/npapi-sdk { };
 
-  npiet = callPackage ../development/interpreters/npiet { };
-
   npth = callPackage ../development/libraries/npth { };
 
   nmap-formatter = callPackage ../tools/security/nmap-formatter { };