python3Packages.parselmouth: init at 0.4.4

pkgs/development/python-modules/parselmouth/default.nix

@@ -0,0 +1,60 @@
+{
+  lib,
+  buildPythonPackage,
+  cmake,
+  fetchFromGitHub,
+  future,
+  numpy,
+  pytest-lazy-fixture,
+  pytestCheckHook,
+  pythonOlder,
+  scikit-build,
+  setuptools,
+}:
+
+buildPythonPackage rec {
+  pname = "parselmouth";
+  version = "0.4.4";
+  pyproject = true;
+  disabled = pythonOlder "3.7";
+
+  src = fetchFromGitHub {
+    owner = "YannickJadoul";
+    repo = "Parselmouth";
+    # Stable branch with cherry picked changes to fit to the newer dependencies versions https://github.com/YannickJadoul/Parselmouth/issues/130
+    rev = "c2cbecc0ce4a0b5d3052cc6c6fbddf4bf133655d";
+    fetchSubmodules = true;
+    hash = "sha256-+6id0PVfpiVjee7O4ZoskNK0dz5ZmTYRTtum3B3tIgE=";
+  };
+
+  configurePhase = ''
+    # doesn't happen automatically
+    export MAKEFLAGS=-j$NIX_BUILD_CORES
+  '';
+
+  build-system = [
+    cmake
+    scikit-build
+    setuptools
+  ];
+
+  dontUseCmakeConfigure = true;
+
+  dependencies = [ numpy ];
+
+  nativeCheckInputs = [
+    future
+    pytest-lazy-fixture
+    pytestCheckHook
+  ];
+
+  pythonImportsCheck = [ "parselmouth" ];
+
+  meta = {
+    description = "Praat in Python, the Pythonic way";
+    homepage = "https://github.com/YannickJadoul/Parselmouth";
+    changelog = "https://github.com/YannickJadoul/Parselmouth/releases/tag/v${version}";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ derdennisop ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -9738,6 +9738,8 @@ self: super: with self; {
 
   parsel = callPackage ../development/python-modules/parsel { };
 
+  parselmouth = callPackage ../development/python-modules/parselmouth { };
+
   parse-type = callPackage ../development/python-modules/parse-type { };
 
   parsimonious = callPackage ../development/python-modules/parsimonious { };