From 1a94bc5d73d803e5d58beec0a260e0c7f5adccda Mon Sep 17 00:00:00 2001
From: Pierre Karashchuk <krchtchk@gmail.com>
Date: Tue, 18 Jun 2019 00:26:35 -0700
Subject: [PATCH] mullvad-vpn: init at 2019.5

---
 .../networking/mullvad-vpn/default.nix        | 93 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 95 insertions(+)
 create mode 100644 pkgs/applications/networking/mullvad-vpn/default.nix

diff --git a/pkgs/applications/networking/mullvad-vpn/default.nix b/pkgs/applications/networking/mullvad-vpn/default.nix
new file mode 100644
index 000000000000..2d5f47ee9826
--- /dev/null
+++ b/pkgs/applications/networking/mullvad-vpn/default.nix
@@ -0,0 +1,93 @@
+{ stdenv, makeWrapper, fetchurl, dpkg
+, alsaLib, atk, cairo, cups, dbus, expat, fontconfig, freetype
+, gdk_pixbuf, glib, gnome2, pango, nspr, nss, gtk3
+, xorg, autoPatchelfHook, systemd, libnotify
+}:
+
+let deps = [
+    alsaLib
+    atk
+    cairo
+    cups
+    dbus
+    expat
+    fontconfig
+    freetype
+    gdk_pixbuf
+    glib
+    gnome2.GConf
+    pango
+    gtk3
+    libnotify
+    xorg.libX11
+    xorg.libXScrnSaver
+    xorg.libXcomposite
+    xorg.libXcursor
+    xorg.libXdamage
+    xorg.libXext
+    xorg.libXfixes
+    xorg.libXi
+    xorg.libXrandr
+    xorg.libXrender
+    xorg.libXtst
+    xorg.libxcb
+    nspr
+    nss
+    systemd
+  ];
+
+in
+
+stdenv.mkDerivation rec {
+  pname = "mullvad-vpn";
+  version = "2019.5";
+
+  src = fetchurl {
+    url = "https://www.mullvad.net/media/app/MullvadVPN-${version}_amd64.deb";
+    sha256 = "542a93521906cd5e97075c9f3e9088c19562b127556a3de151e25bc66b11fe0b";
+  };
+
+  nativeBuildInputs = [
+    autoPatchelfHook
+    dpkg
+  ];
+
+  buildInputs = deps;
+
+  dontBuild = true;
+  dontConfigure = true;
+
+  unpackPhase = "dpkg-deb -x $src .";
+
+  runtimeDependencies = [ systemd.lib libnotify ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/share/mullvad $out/bin
+
+    mv usr/share/* $out/share
+    mv usr/bin/* $out/bin
+    mv opt/Mullvad\ VPN/* $out/share/mullvad
+
+    sed -i 's|\/opt\/Mullvad.*VPN|'$out'/bin|g' $out/share/applications/mullvad-vpn.desktop
+    sed -i 's|\/opt\/Mullvad.*VPN/resources|'$out'/bin|g' $out/share/mullvad/resources/mullvad-daemon.service
+
+    ln -s $out/share/mullvad/mullvad-vpn $out/bin/mullvad-vpn
+    ln -s $out/share/mullvad/resources/mullvad-daemon $out/bin/mullvad-daemon
+
+    mkdir -p $out/etc/systemd/system
+    ln -s $out/share/mullvad/resources/mullvad-daemon.service $out/etc/systemd/system/mullvad-daemon.service
+
+    runHook postInstall
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = "https://github.com/mullvad/mullvadvpn-app";
+    description = "Client for Mullvad VPN";
+    changelog = "https://github.com/mullvad/mullvadvpn-app/blob/${version}/CHANGELOG.md";
+    license = licenses.gpl3;
+    platforms = [ "x86_64-linux" ];
+  };
+
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 9b81ca38714d..d6781fa9867c 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -14347,6 +14347,8 @@ in
 
   morty = callPackage ../servers/web-apps/morty { };
 
+  mullvad-vpn = callPackage ../applications/networking/mullvad-vpn { };
+
   myserver = callPackage ../servers/http/myserver { };
 
   nas = callPackage ../servers/nas { };