From 8c56982378b3e5639abb8639c0a7271474cc052d Mon Sep 17 00:00:00 2001
From: Tyler Langlois <tjl@byu.net>
Date: Sat, 6 Jul 2024 14:42:20 -0600
Subject: [PATCH] goatcounter: init at 2.5.0

---
 pkgs/by-name/go/goatcounter/package.nix | 54 +++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 pkgs/by-name/go/goatcounter/package.nix

diff --git a/pkgs/by-name/go/goatcounter/package.nix b/pkgs/by-name/go/goatcounter/package.nix
new file mode 100644
index 000000000000..208581708837
--- /dev/null
+++ b/pkgs/by-name/go/goatcounter/package.nix
@@ -0,0 +1,54 @@
+{ lib
+, buildGoModule
+, fetchFromGitHub
+, testers
+, goatcounter
+}:
+
+buildGoModule rec {
+  pname = "goatcounter";
+  version = "2.5.0";
+
+  src = fetchFromGitHub {
+    owner = "arp242";
+    repo = "goatcounter";
+    rev = "v${version}";
+    sha256 = "sha256-lwiLk/YYxX4QwSDjpU/mAikumGXYMzleRzmPjZGruZU=";
+  };
+
+  vendorHash = "sha256-YAb3uBWQc6hWzF1Z5cAg8RzJQSJV+6dkppfczKS832s=";
+  subPackages = [ "cmd/goatcounter" ];
+  modRoot = ".";
+
+  # Derived from the upstream build scripts:
+  #
+  # `-trimpath` is used, which `allowGoReference` sets
+  allowGoReference = true;
+  # Flags set in the upstream build.
+  ldflags = [
+    "-s"
+    "-w"
+    "-X zgo.at/goatcounter/v2.Version=${src.rev}"
+  ];
+
+  passthru.tests.version = testers.testVersion {
+    package = goatcounter;
+    command = "goatcounter version";
+    version = "v${version}";
+  };
+
+  meta = {
+    description = "Easy web analytics. No tracking of personal data";
+    changelog = "https://github.com/arp242/goatcounter/releases/tag/${src.rev}";
+    longDescription = ''
+      GoatCounter is an open source web analytics platform available as a hosted
+      service (free for non-commercial use) or self-hosted app. It aims to offer easy
+      to use and meaningful privacy-friendly web analytics as an alternative to
+      Google Analytics or Matomo.
+    '';
+    homepage = "https://github.com/arp242/goatcounter";
+    license = lib.licenses.eupl12;
+    maintainers = with lib.maintainers; [ tylerjl ];
+    mainProgram = "goatcounter";
+  };
+}