lomiri.gmenuharness: init at 0.1.4

pkgs/desktops/lomiri/default.nix

@@ -9,6 +9,7 @@ let
   in {
     #### Development tools / libraries
     cmake-extras = callPackage ./development/cmake-extras { };
+    gmenuharness = callPackage ./development/gmenuharness { };
     lomiri-api = callPackage ./development/lomiri-api { };
   };
 in

pkgs/desktops/lomiri/development/gmenuharness/default.nix

@@ -0,0 +1,86 @@
+{ stdenv
+, lib
+, fetchFromGitLab
+, gitUpdater
+, testers
+, cmake
+, cmake-extras
+, dbus
+, dbus-test-runner
+, glib
+, gtest
+, libqtdbustest
+, lomiri-api
+, pkg-config
+, qtbase
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "gmenuharness";
+  version = "0.1.4";
+
+  src = fetchFromGitLab {
+    owner = "ubports";
+    repo = "development/core/gmenuharness";
+    rev = finalAttrs.version;
+    hash = "sha256-MswB8cQvz3JvcJL2zj7szUOBzKRjxzJO7/x+87m7E7c=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ];
+
+  buildInputs = [
+    cmake-extras
+    glib
+    lomiri-api
+    qtbase
+  ];
+
+  nativeCheckInputs = [
+    dbus
+    dbus-test-runner
+  ];
+
+  checkInputs = [
+    gtest
+    libqtdbustest
+  ];
+
+  cmakeFlags = [
+    "-Denable_tests=${lib.boolToString finalAttrs.doCheck}"
+  ];
+
+  dontWrapQtApps = true;
+
+  doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
+
+  enableParallelChecking = false;
+
+  checkPhase = ''
+    runHook preCheck
+
+    dbus-test-runner -t make -p test -p "''${enableParallelChecking:+-j $NIX_BUILD_CORES}"
+
+    runHook postCheck
+  '';
+
+  passthru = {
+    tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+    updateScript = gitUpdater { };
+  };
+
+  meta = with lib; {
+    description = "Library to test GMenuModel structures";
+    homepage = "https://gitlab.com/ubports/development/core/gmenuharness";
+    license = licenses.gpl3Only;
+    maintainers = teams.lomiri.members;
+    platforms = platforms.unix;
+    pkgConfigModules = [
+      "libgmenuharness"
+    ];
+  };
+})