vimPlugins.vim-clap: move out of batch updates, 2023-04-02 -> 0.42

pkgs/applications/editors/vim/plugins/generated.nix

@@ -10098,18 +10098,6 @@ final: prev:
     meta.homepage = "https://github.com/rhysd/vim-clang-format/";
   };
 
-  vim-clap = buildVimPluginFrom2Nix {
-    pname = "vim-clap";
-    version = "2023-04-02";
-    src = fetchFromGitHub {
-      owner = "liuchengxu";
-      repo = "vim-clap";
-      rev = "5a3667644ca1beada1c6add865b3f8329b4727bc";
-      sha256 = "1066xdimc4vpqar95hnbwl1f2wijr3yss6z1s16k07ymvi02dgxs";
-    };
-    meta.homepage = "https://github.com/liuchengxu/vim-clap/";
-  };
-
   vim-clojure-highlight = buildVimPluginFrom2Nix {
     pname = "vim-clojure-highlight";
     version = "2015-07-05";

pkgs/applications/editors/vim/plugins/overrides.nix

@@ -90,9 +90,7 @@
 , makeWrapper
 , procps
 
-  # vim-clap dependencies
-, libgit2
-, libiconv
+  # sg-nvim dependencies
 , openssl
 , pkg-config
 
@@ -1159,35 +1157,7 @@ self: super: {
     passthru.python3Dependencies = ps: with ps; [ beancount ];
   });
 
-  vim-clap = super.vim-clap.overrideAttrs (old: {
-    preFixup =
-      let
-        maple-bin = rustPlatform.buildRustPackage {
-          name = "maple";
-          inherit (old) src;
-
-          nativeBuildInputs = [
-            pkg-config
-          ];
-
-          buildInputs = [
-            openssl
-          ] ++ lib.optionals stdenv.isDarwin [
-            CoreServices
-            curl
-            libgit2
-            libiconv
-          ];
-
-          cargoHash = "sha256-BFUC6fQ5LpTKx2ztCuFVzXTWzSDl03VYsmVcxBXbiT4=";
-        };
-      in
-      ''
-        ln -s ${maple-bin}/bin/maple $target/bin/maple
-      '';
-
-    meta.platforms = lib.platforms.all;
-  });
+  vim-clap = callPackage ./vim-clap { };
 
   vim-codefmt = super.vim-codefmt.overrideAttrs (old: {
     dependencies = with self; [ vim-maktaba ];

pkgs/applications/editors/vim/plugins/vim-clap/default.nix

@@ -0,0 +1,66 @@
+{ lib
+, rustPlatform
+, fetchFromGitHub
+, pkg-config
+, libgit2
+, zlib
+, stdenv
+, darwin
+, vimUtils
+}:
+
+let
+  version = "0.42";
+
+  src = fetchFromGitHub {
+    owner = "liuchengxu";
+    repo = "vim-clap";
+    rev = "v${version}";
+    hash = "sha256-Vd0T8RrpJb2aybuxIY2PaLT7bDtbkZF/N9VgbcZfPIE=";
+  };
+
+  meta = with lib; {
+    description = "A modern performant fuzzy picker for Vim and NeoVim";
+    homepage = "https://github.com/liuchengxu/vim-clap";
+    changelog = "https://github.com/liuchengxu/vim-clap/blob/${src.rev}/CHANGELOG.md";
+    license = licenses.mit;
+    maintainers = with maintainers; [ ];
+  };
+
+  maple = rustPlatform.buildRustPackage {
+    pname = "maple";
+    inherit version src meta;
+
+    cargoLock = {
+      lockFile = ./Cargo.lock;
+      outputHashes = {
+        "subprocess-0.2.10" = "sha256-WcGrJ103ofGlQwi32kRGM3Z+uvKSCFBmFZbZXAtuWwM=";
+      };
+    };
+
+    nativeBuildInputs = [
+      pkg-config
+    ];
+
+    buildInputs = [
+      libgit2
+      zlib
+    ] ++ lib.optionals stdenv.isDarwin [
+      darwin.apple_sdk.frameworks.CoreFoundation
+      darwin.apple_sdk.frameworks.Security
+    ];
+  };
+in
+
+vimUtils.buildVimPluginFrom2Nix {
+  pname = "vim-clap";
+  inherit version src meta;
+
+  postInstall = ''
+    ln -s ${maple}/bin/maple $out/bin/maple
+  '';
+
+  passthru = {
+    inherit maple;
+  };
+}

pkgs/applications/editors/vim/plugins/vim-plugin-names

@@ -850,7 +850,6 @@ https://github.com/kristijanhusak/vim-carbon-now-sh/,,
 https://github.com/m-pilia/vim-ccls/,,
 https://github.com/t9md/vim-choosewin/,,
 https://github.com/rhysd/vim-clang-format/,,
-https://github.com/liuchengxu/vim-clap/,,
 https://github.com/guns/vim-clojure-highlight/,,
 https://github.com/guns/vim-clojure-static/,,
 https://github.com/rstacruz/vim-closer/,,