dev/nixpkgs
1
0
Fork 0
Code Issues Pull Requests Actions 2 Packages Projects Releases Wiki Activity

passky-desktop: init at 5.0.0

Browse Source
This commit is contained in:
Alessandro Barenghi 2021-12-01 18:32:25 +01:00
parent f1871f04f3
commit 6106be44f8
No known key found for this signature in database
GPG Key ID: 14E259475412EC24
2 changed files with 61 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

59
pkgs/applications/misc/passky-desktop/default.nix Normal file
View File

@ -0,0 +1,59 @@
{ lib, stdenv, fetchurl, appimageTools, undmg }:
let
pname = "passky-desktop";
version = "5.0.0";
srcs = {
x86_64-linux = fetchurl {
url = "https://github.com/Rabbit-Company/Passky-Desktop/releases/download/v${version}/Passky-${version}.AppImage";
sha256 = "19sy9y2bcxrf10ifszinh4yn32q3032h3d1qxm046zffzl069807";
};
x86_64-darwin = fetchurl {
url = "https://github.com/Rabbit-Company/Passky-Desktop/releases/download/v${version}/Passky-${version}.dmg";
sha256 = "sha256-lclJOaYe+2XeKhJb2WcOAzjBMzK3YEmlS4rXuRUJYU0=";
};
};
src = srcs.${stdenv.hostPlatform.system} or (throw "Unsupported system: ${stdenv.hostPlatform.system}");
appimageContents = appimageTools.extract { inherit pname version src; };
meta = with lib; {
homepage = "https://passky.org";
downloadPage = "https://github.com/Rabbit-Company/Passky-Desktop/releases";
license = licenses.gpl3Only;
maintainers = with maintainers; [ akkesm ];
platforms = builtins.attrNames srcs;
};
linux = appimageTools.wrapType2 {
inherit pname version src meta;
extraInstallCommands = ''
mv $out/bin/${pname}-${version} $out/bin/${pname}
install -D ${appimageContents}/passky.desktop \
$out/share/applications/${pname}.desktop
substituteInPlace $out/share/applications/${pname}.desktop \
--replace 'Exec=AppRun' 'Exec=${pname}'
cp -r ${appimageContents}/usr/share/icons $out/share
'';
};
darwin = stdenv.mkDerivation {
inherit pname version src meta;
nativeBuildInputs = [ undmg ];
sourceRoot = ".";
installPhase = ''
mkdir -p $out/Applications
cp -r *.app $out/Applications
'';
};
in
if stdenv.isDarwin
then darwin
else linux

2
pkgs/top-level/all-packages.nix
View File

@ -25862,6 +25862,8 @@ with pkgs;
pass-secret-service = callPackage ../applications/misc/pass-secret-service { };
passky-desktop = callPackage ../applications/misc/passky-desktop { };
pinboard = with python3Packages; toPythonApplication pinboard;
pinboard-notes-backup = haskell.lib.compose.justStaticExecutables haskellPackages.pinboard-notes-backup;