From 512f0874a16902ef05796d5cae5d124dfd6b0624 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Bj=C3=B8rn=20Forsman?= <bjorn.forsman@gmail.com>
Date: Sat, 18 May 2013 20:13:32 +0200
Subject: [PATCH] wildmidi: new package

WildMIDI is a simple software midi player which has a core softsynth
library that can be use with other applications.

I have tested the wildmidi executable with a MIDI file. It works.
---
 .../libraries/wildmidi/default.nix            | 36 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 ++
 2 files changed, 38 insertions(+)
 create mode 100644 pkgs/development/libraries/wildmidi/default.nix

diff --git a/pkgs/development/libraries/wildmidi/default.nix b/pkgs/development/libraries/wildmidi/default.nix
new file mode 100644
index 000000000000..0c51bd2d38b5
--- /dev/null
+++ b/pkgs/development/libraries/wildmidi/default.nix
@@ -0,0 +1,36 @@
+{ stdenv, fetchurl, alsaLib, freepats }:
+
+stdenv.mkDerivation rec {
+  name = "wildmidi-0.2.3.5";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/project/wildmidi/wildmidi/${name}.tar.gz";
+    sha256 = "0m75753mn0rbwja180c2qk53s149wp4k35dijr2i6pa7sc12fr00";
+  };
+
+  # NOTE: $out in configureFlags, like this:
+  #   configureFlags = "--disable-werror --with-wildmidi-cfg=$out/etc/wildmidi.cfg";
+  # is not expanded, so use this workaround:
+  preConfigure = ''
+    configureFlags="--disable-werror --with-wildmidi-cfg=$out/etc/wildmidi.cfg"
+  '';
+
+  buildInputs = [ alsaLib ];
+
+  postInstall = ''
+    mkdir "$out"/etc
+    echo "dir ${freepats}" > "$out"/etc/wildmidi.cfg
+    echo "source ${freepats}/freepats.cfg" >> "$out"/etc/wildmidi.cfg
+  '';
+
+  meta = {
+    description = "Software MIDI player and library";
+    longDescription = ''
+      WildMIDI is a simple software midi player which has a core softsynth
+      library that can be use with other applications.
+    '';
+    homepage = http://wildmidi.sourceforge.net/;
+    # The library is LGPLv3, the wildmidi executable is GPLv3
+    license = stdenv.lib.licenses.lgpl3;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 96ca1807be4b..51915ae3a53c 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -5204,6 +5204,8 @@ let
       inherit libpng;
     };
 
+  wildmidi = callPackage ../development/libraries/wildmidi { };
+
   wvstreams = callPackage ../development/libraries/wvstreams { };
 
   wxGTK = wxGTK28;