udiskie: move to all-packages

This is an application, not a python library and should therefore be in
its own package.

pkgs/applications/misc/udiskie/default.nix

@@ -0,0 +1,43 @@
+{ stdenv, fetchFromGitHub, asciidoc-full, gettext
+, gobjectIntrospection, gtk3, hicolor_icon_theme, libnotify
+, pythonPackages, udisks2, wrapGAppsHook }:
+
+pythonPackages.buildPythonApplication rec {
+  name = "udiskie-${version}";
+  version = "1.5.1";
+
+  src = fetchFromGitHub {
+    owner = "coldfix";
+    repo = "udiskie";
+    rev = version;
+    sha256 = "01x5fvllb262x6r3547l23z7p6hr7ddz034bkhmj2cqmf83sxwxd";
+  };
+
+  buildInputs = [
+    asciidoc-full        # For building man page.
+    hicolor_icon_theme
+    wrapGAppsHook
+  ];
+
+  propagatedBuildInputs = [
+    gettext gobjectIntrospection gtk3 libnotify pythonPackages.docopt
+    pythonPackages.pygobject3 pythonPackages.pyyaml udisks2
+  ];
+
+  postBuild = "make -C doc";
+
+  postInstall = ''
+    mkdir -p $out/share/man/man8
+    cp -v doc/udiskie.8 $out/share/man/man8/
+  '';
+
+  # tests require dbusmock
+  doCheck = false;
+
+  meta = with stdenv.lib; {
+    description = "Removable disk automounter for udisks";
+    license = licenses.mit;
+    homepage = https://github.com/coldfix/udiskie;
+    maintainers = with maintainers; [ AndersonTorres ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -14672,6 +14672,8 @@ in
 
   udevil = callPackage ../applications/misc/udevil {};
 
+  udiskie = callPackage ../applications/misc/udiskie { };
+
   sakura = callPackage ../applications/misc/sakura {
     vte = gnome3.vte;
   };

pkgs/top-level/python-packages.nix

@@ -27121,49 +27121,8 @@ in modules // {
     };
   };
 
-  udiskie = buildPythonApplication rec {
+  # For backwards compatibility. Please use nixpkgs.udiskie instead.
-    version = "1.5.1";
+  udiskie = pkgs.udiskie.override { pythonPackages = self; };
-    name = "udiskie-${version}";
-
-    src = pkgs.fetchFromGitHub {
-      owner = "coldfix";
-      repo = "udiskie";
-      rev = version;
-      sha256 = "01x5fvllb262x6r3547l23z7p6hr7ddz034bkhmj2cqmf83sxwxd";
-    };
-
-    preConfigure = ''
-      export XDG_RUNTIME_DIR=/tmp
-    '';
-
-    buildInputs = [
-      pkgs.asciidoc-full        # For building man page.
-      pkgs.hicolor_icon_theme
-      pkgs.wrapGAppsHook
-    ];
-
-    propagatedBuildInputs = with self; [
-      pkgs.gobjectIntrospection pkgs.gtk3 pyyaml pygobject3
-      pkgs.libnotify pkgs.udisks2 pkgs.gettext self.docopt
-    ];
-
-    postBuild = "make -C doc";
-
-    postInstall = ''
-      mkdir -p $out/share/man/man8
-      cp -v doc/udiskie.8 $out/share/man/man8/
-    '';
-
-    # tests require dbusmock
-    doCheck = false;
-
-    meta = {
-      description = "Removable disk automounter for udisks";
-      license = licenses.mit;
-      homepage = https://github.com/coldfix/udiskie;
-      maintainers = with maintainers; [ AndersonTorres ];
-    };
-  };
 
   # Should be bumped along with EFL!
   pythonefl = buildPythonPackage rec {